// ROI_Color_Coder.ijm
//
// This macro colorizes ROIs listed in the Manager by matching ROI measurements to an index
// of a LUT file. It can be used, e.g., to obtain a particle-size 'heat-map' of segmented
// objects. It will terminate if the LUT file cannot be read.
//
// More info at http://imagejdocu.tudor.lu/doku.php?id=macro:roi_color_coder
//
// N.B.:
// 1) Save this file in the plugins directory and it will be available in the Plugins Menu;
// 2) Edit your preferred LUT and save it as 'rmanager[...].lut' in the ImageJ/luts directory 
//    to have it loaded by default;
// 3) Use the 'glasbey' lookup table to label ROIs randomly or ramp LUTs ('001-fire','002-spectrum',
//    'hue', etc.) to obtain heat-map codes;
//    glasbey LUT:                        http://rsb.info.nih.gov/ij/download/luts/glasbey.lut
//    heat-map LUTs (and several others): http://rsb.info.nih.gov/ij/download/luts/luts.zip
// 4) If the Results table has more rows then the number of items in the ROI Manager list, the macro
//    will ignore the extra rows
//
// tf, 2009.11.26 

//revised: 2009.12.01: Fixed labels misalignment in legend


// For a demo, make sure you have at least one tab-delimited text LUT file in your ImageJ/luts folder
// and run the three lines below
   // run("Blobs (25K)");
   // setAutoThreshold;
   // run("Analyze Particles...", "display clear add")


macro "ROI Color Coder" {
    requires("1.43j");
    if(nImages==0 || nResults==0 || nResults<roiManager("count"))
        verboseExit("This macro requires an open image and a Results table with at least the same",
                    "number of rows as the number of items in the ROI Manager list.");

    parameters = newArray("AR", "Area", "Circ.", "Feret", "IntDen", "Max", "Mean", "Median", "Min",
                          "Mode", "Perim.", "Round", "Solidity", "StdDev", "Other..."); 
    luts = getLutList();
    
    Dialog.create('ROI Color Coder');
    Dialog.addChoice("Colorize ROIs in manager by:", parameters, "Area");
    Dialog.addChoice("Using the lookup table:", luts);
    Dialog.addString("Match last LUT index to:", "");
    Dialog.addMessage("(Leave blank to use the highest value in the measurement column)");
    Dialog.addCheckbox("Display color code legend",true);
    Dialog.addString("Unit:", "um^2");
    Dialog.show;
    parameter = Dialog.getChoice;
    lut = Dialog.getChoice;
    max = Dialog.getString;
    legend = Dialog.getCheckbox;
    unit = Dialog.getString;  
    max = d2s(max,2);

    if(parameter=="Other...")
        parameter = getString("Parameter", "");
  
    setBatchMode(true);
    if(isNaN(max)) {
        values = newArray(nResults);
        for(i=0; i<nResults; i++)
            values[i] = getResult(parameter,i);  
        Array.getStatistics(values, min, max);
        if(max==-1/0) 
            exit("Results table does not contain valid data for \""+parameter+"\".");        
    }
    
    roiColors = loadColorsfromLut(""+lut+".lut");
    countNaN = 0;
    for(i=0; i<nResults; i++) {
        size = getResult(parameter,i);
        lutIndex = round((size*255)/max);
        if(isNaN(lutIndex))
            countNaN++;    // just in case the results table has been edited elsewhere
        lutIndex = minOf(lutIndex,255);
        roiManager("select", i);
        roiManager("Set Line Width", 3);
        roiManager("Set Color", roiColors[lutIndex]);
    }
    roiManager("Show All");

    if(legend) {
        saveSettings;
        setBackgroundColor(255,255,255);

        rampW = 256; rampH = 32; fontS = 14; nTicks = 14;
        canvasH = fontS+rampW-1; canvasW = rampW/2; 
    
        newImage("ColorCodeLegend", "32-bit Ramp", rampW, rampH, 1);
        run("Canvas Size...", "width="+ rampW+1 +" height=&rampH position=Center-Left");  
        setMetadata("Label", "Param:"+parameter+", LUT: "+lut);
        run(lut); run("RGB Color");

        setColor(0); setLineWidth(1); setFont("Monospaced",fontS);
        drawLine(0, rampH-1, rampW, rampH-1); drawLine(0, 0, rampW, 0); // make vertical scale lines

        run("Rotate 90 Degrees Left"); 
        run("Canvas Size...", "width=&canvasW height=&canvasH position=Center-Left");

        yPos = fontS/2; // ramp is now a 32x256 rectangle at (0, 6);
        for (i=0;i<=nTicks;i++) {
            if(i%2)
                l = 4; // make shorter divison ticks when there are no labels
            else {
                l = 8; // draw scale ticks and scale values
                drawString(d2s(i*max/nTicks,2), rampH+1, (canvasH+2)-(i*rampW/nTicks)); // 2 pixels shift
            }
            drawLine(rampH-l, canvasH-yPos, rampH-1, canvasH-yPos);
            drawLine(0, canvasH-yPos, l, canvasH-yPos);  // make ticks in both sides of the ramp
            yPos = yPos+(rampW/nTicks);
       }
        
        unit = replace(unit,"(?<![A-Za-z0-9])u(?=m)",fromCharCode(181)); // find all 'um' not preceded
        unit = replace(unit,"\\^2",fromCharCode(178));                   // by alphanumeric characters
        unit = replace(unit,"\\^3",fromCharCode(179));                   // and all '^2' and '^3' symbols
        uW = minOf(getStringWidth(unit),rampH); spacer = (rampH-uW)/2;
        run("Canvas Size...", "width=&canvasW height="+canvasH+fontS+" position=Bottom-Left");
        drawString(unit, spacer, fontS);
        restoreSettings;
    }
    
    setBatchMode("exit & display");
    if(countNaN!=0)
        showMessage("Some "+ parameter +" values could not be retrieved.\n"+
                    countNaN+" ROI(s) labeled with default color."); 
    call("java.lang.System.gc");                               
} 
 
function getLutList() {
    lutdir = getDirectory("luts");
    if(!File.exists(lutdir))
        verboseExit("Could not find luts folder","");
    rawlist = getFileList(lutdir);
    if(rawlist.length==0)
        verboseExit("No LUTS in the ImageJ/luts folder","");
    count = 0;
    for(i=0; i< rawlist.length; i++) {
        header = File.openAsRawString(lutdir+rawlist[i],5);
        byte1 = substring(header, 0, 1);
        if(endsWith(rawlist[i], ".lut")) {
            if(header == toLowerCase("Index") || !isNaN(byte1))
                count++;
        }
    }    
    if(count==0)
        verboseExit("No tab-delimited text LUTS in the ImageJ/luts folder","");
    list = newArray(count);
    index = 0; def = -1;
    for(i=0; i< rawlist.length; i++) { 
        if(endsWith(rawlist[i], ".lut")) {
            header = File.openAsRawString(lutdir+rawlist[i],5);
            byte1 = substring(header, 0, 1);
            if(header == toLowerCase("Index") || !isNaN(byte1)) {
                lutnm= substring(rawlist[i], 0, lengthOf(rawlist[i])-4);
                if(startsWith(lutnm, "rmanager"))
                    def = index;
                list[index++] = lutnm;
            }    
        }          
    }
    if(def!=-1) {   // a "roimanager.lut" was found. Make it the 1st item in list
        old1st = list[0]; new1st = list[def];
        list[def] = old1st;
        Array.sort(list);
        list[0] = new1st;
    }
    showStatus("Found "+count+" tab-delimited LUT files (out of "+rawlist.length+")");     
    return list;
}    
 
function loadColorsfromLut(lut) {
    path = getDirectory("luts")+lut;
    list = File.openAsRawString(path);
    rgbColor = split(list,"\n");
    if(rgbColor.length<255 || rgbColor.length>257)
        verboseExit("Error reading "+path, "Reason: Found unexpected number of columns");
    hexColor = newArray(256);
    firstStrg = substring(rgbColor[0], 0, 1);
    if (isNaN(firstStrg))
        k = 1;    // the lut file has a header (Index Red Green Blue)
     else
        k = 0;    // there is no header. First row is index 0
    for(i=k; i<256; i++) {
        hex = rgbToHex(rgbColor[i]);    
        hexColor[i] = hex;
    }
    return  hexColor;  
}

function rgbToHex(color) {
    color1 = split(color,"\t");
    if(color1.length==1)
        color1 = split(color," ");
    if(color1.length==1)
        verboseExit("Chosen LUT does not seem to be either a tab-delimited",
                    "or a space-delimited text file");
    if(color1.length==4)
        i = 1;    // first column of the lut file is the index number
    else
        i = 0;    // first column of the lut file is the red value
    r = color1[0+i]; g = color1[1+i]; b = color1[2+i];
    return ""+toHex(r)+""+toHex(g)+""+toHex(b);
}

function toHex(n) {
    n = parseInt(n);
    if(n==0 || isNaN(n))
        return "00";
    n = maxOf(0,n); n = minOf(n,255); n = round(n);
    hex = ""+substring("0123456789ABCDEF",((n-n%16)/16),((n-n%16)/16)+1)+
          substring("0123456789ABCDEF",(n%16),(n%16)+1);
    return hex;
}

function verboseExit(line1, line2) {
    msg = line1+"\n"+
          line2+"\n \n"+
          "ROI Color Coder screens all the LUT files in the '/ImageJ/luts/' folder selecting\n"+
          "those saved as tab-delimited text files. A chosen LUT is then used to colorize\n"+
          "ROIs in the Manager, by matching LUT indexes to measurements in the Results\n"+
          "table. It is a complement to the 'Analyze>Analyze Particles...' command.\n \n"+
          "    - Several tab-delimited lookup tables can be obtained from the IJ web site:\n"+
          "        - http://rsb.info.nih.gov/ij/download/luts/luts.zip\n \n"+
          "    - Customize your own tab-delimited LUT file using several plugins, e.g.:\n"+
          "        - LUT Lister (http://rsbweb.nih.gov/ij/plugins/lut-lister.html)\n"+
          "        - LUT Panel (http://rsbweb.nih.gov/ij/plugins/lut-panel.html)";
    exit(msg);
}