// "AdvancedPlots" macros
// These macros demonstrate how to use the toUnscaled() 
// and toScaled() functions with plot windows.
// They require ImageJ 1.45n or later.
//
// There are five macros:
//    "Highlight and Annotate Area [F1]"
//    "Qualify Roi [F2]"
//    "Filled Plot [F3]"
//    "Custom Markers [F4]"
//    "Zoom in Plot [F5]"
//
// vischer at science.uva.nl
// 05.09.11 22:41

macro "Highlight and Annotate Area [F1]" {
	requires("1.45n");
	left = -1;
	right = 5;
	bottom = -0.2;
	top = 1.2;
	nPoints = 200;
	range = right - left;
	
	xValues = newArray(nPoints);
	yValues = newArray(nPoints);
	Plot.create("Gauss-Ellipse-Match", "X", "Y");
	Plot.setLimits(left, right, bottom, top );
	sigma = 2;
	ampl = 1;	 
	x0 = 2;
	radiusX = sigma /sqrt(2);//horizontal radius
	for (p = 0; p < nPoints; p++){
		x = p/nPoints * range + left;
		y = ampl * exp(-pow(x - x0, 2)/(sigma * sigma * 2));
		xValues[p] = x;
		yValues[p] = y;
	}
	Plot.setColor("blue");
	Plot.add("line", xValues, yValues);
	Plot.setColor("red");
	Plot.drawLine(x0, ampl/2, x0+radiusX, ampl/2);
	Plot.show;
	
	hookLeft = x0-radiusX;
	hookTop =	 ampl;
	hookBottom =	0;
	hookRight = x0+radiusX;
	toUnscaled(hookLeft, hookTop);
	toUnscaled(hookRight, hookBottom);
	
	makeOval(hookLeft, hookTop, hookRight - hookLeft, hookBottom - hookTop);
	changeValues(0x00ffffff, 0x00ffffff, 0x00ccddff);
	run("Select None");
	setColor(0xff0000);
	x = x0;
	y = ampl/2;
	toUnscaled(x, y);
	drawString("r = sigma / sqrt(2)", x, y-2);
}

macro "Qualify ROI [F2]" {
	k1000 = 1000;
	xValues = newArray(k1000);
	yValues = newArray(k1000);
	for (jj = 0; jj <k1000; jj++){
		noise = pow(random- 0.5, 3) * 20;
		xValues[jj] = jj/100;					
		yValues[jj] = sqrt(jj)/5 + noise;
	}
	
	Plot.create("Qualify Roi", "X", "Y");
	Plot.setLimits(0, 10, 0, 10 );
	Plot.setColor("blue");
	Plot.add("dots", xValues, yValues); 
	Plot.show;
	
	waitForUser("Create ROI for qualifying, then click OK");
	if (selectionType == -1) exit ("No Selection found");
	qualifiedX = newArray(k1000);
	qualifiedY = newArray(k1000);
	q = 0;
	for (jj = 0; jj <k1000; jj++){
		x = xValues[jj];
		y = yValues[jj];
		toUnscaled(x, y);
		if (selectionContains(x, y)){
			qualifiedX[q] = xValues[jj];
			qualifiedY[q++] = yValues[jj];
		}
	}
	qualifiedX = Array.trim(qualifiedX, q);
	qualifiedY = Array.trim(qualifiedY, q);
	
	Plot.create("Qualify Roi", "X", "Y");
	Plot.setLimits(0, 10, 0, 10 );
	Plot.setColor("blue");
	Plot.add("dots", xValues, yValues); 
	Plot.setColor("red");
	Plot.add("circles", qualifiedX, qualifiedY); 
	Plot.update;	
}


macro "Filled Plot [F3]"{
	left = 0;
	right = 4;
	bottom = 0;
	top = 1.2;
	nPoints = 200;
	range = right - left;
	
	xValues = newArray(nPoints);
	yValues = newArray(nPoints);
	Plot.create("Filled Plot", "X", "Y");
	Plot.setLimits(left, right, bottom, top );
	sigma = 0.4;
	ampl = 1;	 
	x0 = 2;
	for (p = 0; p < nPoints; p++){
		x = p/nPoints * range + left;
		y = ampl * exp(-pow(x - x0, 2)/(sigma * sigma * 2));
		xValues[p] = x;
		yValues[p] = y;
	}
	Plot.setColor("blue");
	Plot.add("line", xValues, yValues);
	Plot.show;
	
	//add two points for base line:
	polygonX =	 newArray(nPoints + 2);		
	polygonY =	 newArray(nPoints + 2);
	for (jj = 0; jj<nPoints; jj++){
		polygonX[jj+1] = xValues[jj];
		polygonY[jj+1] = yValues[jj];
	}
	polygonX[0] = polygonX[1];
	polygonX[nPoints + 1] = polygonX[nPoints];
	polygonY[0] = bottom;
	polygonY[nPoints + 1] = bottom;
	
	toUnscaled(polygonX, polygonY);
	makeSelection("polygon", polygonX, polygonY);
	changeValues(0xffffff, 0xffffff, 0xaaaaff);
	run("Select None");
}


macro "Custom Markers [F4]"{
	makeCustomIcons();
	waitForUser("Using selection in RGB image as custom marker...");
	getSelectionBounds(left, top, ww, hh);
	run("Copy");
	
	xValues = newArray(11, 20, 33, 46, 61, 82);
	yValues = newArray(1,	 10, 18, 22, 25, 28);
	
	Plot.create("Custom Markers", "X", "Y");
	Plot.setLimits(0, 90, 0, 40 );
	Plot.setColor("lightGray");
	Plot.add("line", xValues, yValues); 
	Plot.show;
	selectImage(nImages);
	toUnscaled(xValues, yValues);
	for (jj = 0; jj < xValues.length; jj++){
		makeRectangle(round(xValues[jj] -ww/2), round(yValues[jj] -hh/2), ww, hh);
		setPasteMode("Transparent-white");
		run("Paste");
	}
	setPasteMode("Copy");
	run("Select None");
}


macro "Zoom in Plot [F5]"{
	left = 0;
	right = 4;
	bottom = 0;
	top = 1.2;
	nPoints = 2000;
	range = right - left;
	
	xValues = newArray(nPoints);
	yValues = newArray(nPoints);
	Plot.create("Zoom in Plot", "X", "Y");
	Plot.setLimits(left, right, bottom, top );
	sigma = 0.05;
	ampl = 1;	 
	x0 = 2;
	for (p = 0; p < nPoints; p++){
		x = p/nPoints * range + left;
		y = ampl * exp(-pow(x - x0, 2)/(sigma * sigma * 2));
		xValues[p] = x;
		yValues[p] = y;
	}
	Plot.setColor("blue");
	Plot.add("line", xValues, yValues);
	Plot.show;
	
	waitForUser("Create ROI for zooming, then click OK");
	if (selectionType == -1) exit ("No Selection found");				 
	getSelectionBounds(xmin, ymin, w, h);
	ymin += h;
	xmax = xmin + w;
	ymax = ymin - h;
	toScaled(xmin, ymin);
	toScaled(xmax, ymax);
	Plot.create("Zoom to ROI", "X", "Y");
	Plot.setLimits(xmin, xmax, ymin, ymax );
	Plot.setColor("blue");
	Plot.add("line", xValues, yValues); 
	Plot.show;
}

function makeCustomIcons(){
	newImage("Custom Icons", "RGB-Color White", 500, 21, 1);
	random("seed", 5);
	for (x = 10; x<=240; x+= 30){
		setForegroundColor(random*256, random*256, random*256);
		fillOval(x-8, 10-1, 17, 3);
		fillOval(x-1, 10-8, 3, 17);
	}
	setFont("Monospaced", 12, "antialiased");
	drawString("A		B		C		D		E		F", 248, 17);
	makeRectangle(0, 0, 21, 21);
}